10 PRINT "*** ACEY DUCEY : B.A.S.I.C ***"
20 DIM WALLET
30 DIM CARD
40 DIM CARDS(3)
50 DIM RESP
60 DIM BET
70 DIM QUESTION$
80 DIM C
90 RESP = 0
100 GOSUB 4000
120 IF RESP = 1 THEN GOSUB 6000
200 REM === RUNNING LOOP ===
210 WALLET = 100
300 REM === GAME LOOP ===
310 PRINT "YOU NOW HAVE" WALLET "DOLLARS"
320 CARDS(0) = 0 : CARDS(1) = 0 : CARDS(2) = 0
330 C = 0 : GOSUB 7000
340 C = 1 : GOSUB 7000
350 GOSUB 1000
360 IF BET = 0 THEN GOTO 8000
370 C = 2 : GOSUB 7000
380 IF CARDS(2) > CARDS(0) AND CARDS(2) < CARDS(1) THEN GOTO 500
390 IF CARDS(2) > CARDS(1) AND CARDS(2) < CARDS(0) THEN GOTO 500
400 PRINT "SORRY, YOU LOSE."
410 WALLET = WALLET - BET
420 IF WALLET > 0 THEN GOTO 300
430 PRINT "SORRY FRIEND, YOU ARE BROKE."
440 GOTO 8000
500 PRINT "YOU WIN!!!"
510 WALLET = WALLET + BET
520 GOTO 300
1000 REM === ASK FOR BET ===
1010 PRINT "WHAT IS YOUR BET?"
1020 INPUT BET
1030 IF BET > -1 THEN GOTO 1060
1040 PRINT "PLEASE BET A NON-NEGATIVE AMOUNT."
1050 GOTO 1010
1060 IF BET < WALLET + 1 THEN RETURN
1070 PRINT "SORRY MY FRIEND, BUT YOU BET TOO MUCH."
1080 PRINT "YOU HAVE ONLY" WALLET "DOLLARS TO BET."
1090 GOTO 1010
2000 REM === ASK A QUESTION ===
2010 PRINT QUESTION$
2020 INPUT ANS$
2030 IF ANS$="YES" OR ANS$="Y" OR ANS$="yes" OR ANS$="y" THEN RESP=1:RETURN
2040 IF ANS$="NO"OR ANS$="N" OR ANS$="no" OR ANS$="n" THEN RESP=0:RETURN
2050 PRINT "PLEASE ANSWER ""YES"" OR ""NO"""
2060 GOTO 2010
3000 REM === ASK TO PLAY AGAIN ===
3010 QUESTION$ = "DO YOU WANT TO PLAY AGAIN?"
3020 GOSUB 2000
3030 RETURN
4000 REM === ASK TO SEE THE RULES ===
4010 QUESTION$ = "DO YOU WANT TO SEE THE RULES?"
4020 GOSUB 2000
4030 RETURN
5000 REM === DISPLAY CARD ===
5010 IF CARD = 11 THEN PRINT "JACK" : RETURN
5020 IF CARD = 12 THEN PRINT "QUEEN" : RETURN
5030 IF CARD = 13 THEN PRINT "KING" : RETURN
5040 IF CARD = 14 THEN PRINT "ACE" : RETURN
5050 PRINT CARD : RETURN
6000 REM === DISPLAY RULES ===
6010 PRINT "ACEY DUCEY IS PLAYED IN THE FOLLOWING MANNER:"
6020 PRINT "THE DEALER (COMPUTER) DEALS TWO CARDS FACE UP"
6030 PRINT "YOU HAVE THE OPTION TO BET OR NOT BET DEPENDING"
6040 PRINT "ON WHETHER OR NOT YOU FEEL THE NEXT CARD WILL"
6050 PRINT "HAVE A VALUE BETWEEN THE FIRST TWO."
6060 PRINT " "
6070 PRINT "IF YOU DO NOT WANT TO BET, INPUT A 0 (ZERO)"
6080 RETURN
7000 REM === SELECT CARD ===
7010 RANDOMIZE TIMER
7020 CARD = INT(RND(0)*13)+2
7030 IF CARD = CARDS(0) THEN GOTO 7010
7040 IF CARD = CARDS(1) THEN GOTO 7010
7050 IF CARD = CARDS(2) THEN GOTO 7010
7060 CARDS(C) = CARD
7070 GOSUB 5000
7080 RETURN
8000 PRINT "*** GAME OVER ***"
8010 RESP = 0 : GOSUB 3000
8020 IF RESP = 1 THEN GOTO 200
8030 PRINT "OK, HOPE YOU HAD FUN."
8040 PRINT "THANKS FOR PLAYING!"
8050 END